uptimeify_im_channel

An Incident Management paging channel (Slack incoming webhook, generic webhook or email). Escalation tiers and the organization fallback page through it. Incident Management must be active for the organization. The webhook URL and header values are secrets: the API never returns them, so they are write-only here. Import with the numeric id.

Example UsageCopy Anchor Link

variable "slack_webhook_url" {
  type      = string
  sensitive = true
}

# Organization-wide Slack channel, also usable as the escalation fallback.
resource "uptimeify_im_channel" "ops_slack" {
  name               = "Ops Slack"
  type               = "slack"
  webhook_url_wo     = var.slack_webhook_url
  secrets_wo_version = 1 # bump to resend the URL after rotating it
}

# Team-scoped email channel.
resource "uptimeify_im_channel" "dba_mail" {
  name    = "DBA mailbox"
  type    = "email"
  team_id = 9
  email   = "dba-oncall@example.com"
}

resource "uptimeify_im_org_settings" "this" {
  fallback_channel_id = tonumber(uptimeify_im_channel.ops_slack.id)
}

SchemaCopy Anchor Link

RequiredCopy Anchor Link

• name (String) 1 to 120 characters, no surrounding whitespace.
• type (String) webhook, slack or email.

OptionalCopy Anchor Link

NOTE: Write-only arguments are supported in Terraform 1.11 and later.

• email (String) type = "email": recipient address (required there).
• headers_wo (Map of String, Sensitive, Write-only) webhook/slack: extra request headers (no Host). Write-only: sent on create and whenever secrets_wo_version changes, then replacing the stored set (unset = remove all). The names are readable as header_names.
• is_active (Boolean) Default true. The organization fallback channel cannot be deactivated.
• secrets_wo_version (Number) Change to resend webhook_url_wo and headers_wo.
• team_id (Number) Team of the organization; unset = organization-wide channel.
• webhook_url_wo (String, Sensitive, Write-only) webhook/slack: public http(s) URL, required on create. Write-only: sent on create, on a type change and whenever secrets_wo_version changes.

Read-OnlyCopy Anchor Link

• created_at (String)
• has_webhook_url (Boolean) Whether a webhook URL is stored.
• header_names (List of String) Names of the stored headers, sorted (values are never returned).
• id (String) Numeric channel id.
• organization_id (Number)
• updated_at (String)

ImportCopy Anchor Link

Import is supported using the following syntax:

The terraform import command can be used, for example:

terraform import uptimeify_im_channel.ops_slack 12